Overbought Oversold indicator

Minitrader1337

Hej!

Det finns en väldigt användbar indikator i Tradingview som heter Overbought Oversold. Här är källan för koden: https://www.tradingview.com/script/RLoA9E77/ . Kan någon hjälpa mig skriva en liknande kod för Hitta KV?

gerteress

Förslag till kod:
ExtOver EOO
Extremt Översålda o Överköpta
local LRSI = RSI(14)[0]
if (LRSI > 15 && LRSI <= 30) {
plot1[0] = Close[0] * 1.5
}
if (LRSI <= 15) {
plot2[0] = Close[0] * 1.5
}
if (LRSI >= 70 && LRSI < 85) {
plot3[0] = Close[0] * 1.5
}
if (LRSI >= 85) {
plot4[0] = Close[0] * 1.5
}
// Visa indikatorn i: Huvudfönster
// Utdata
//plot1 - 2pt 1Översåld
//plot2 - 2pt 2Extremt Översåld
//plot3 - 2pt 3Överköpt
//plot4 - 2pt 4Extremt Överköpt
//Labba gärna med att ändra RSI till 7
//eller ändra värdet 15 till 20 och värdet 85 till 80
//för att få fler träffar

Minitrader1337

Denna koden funkar, men den ger inte ut något. Det står bara " HKScript error: Trying to set "null" ".

gerteress

Minitrader1337
// kod med inparametrar
local LRSI = RSI(p1)[0]
if (LRSI > p2 && LRSI <= 30) {
plot1[0] = Close[0] * 1.5
}
if (LRSI <= p2) {
plot2[0] = Close[0] * 1.5
}
if (LRSI >= 70 && LRSI < p3) {
plot3[0] = Close[0] * 1.5
}
if (LRSI >= p3) {
plot4[0] = Close[0] * 1.5
}
// Visa indikatorn i: Huvudfönster
// Inparametrar:
// p1 = 14
// p2 = 15
// p3 = 85
// Utdata:
//plot1 - 2pt 1Översåld
//plot2 - 2pt 2Extremt Översåld
//plot3 - 2pt 3Överköpt
//plot4 - 2pt 4Extremt Överköpt
//Labba gärna med att ändra RSI till 7
//eller ändra värdet 15 till 20 och värdet 85 till 80
//för att få fler träffar

Vinc

Hej!
Har byggt enligt det som ligger på tradingview och jämfört med Netflix charten som visas och vad jag kan se så stämmer linjerna överens både i HK och tradingview.
Glöm inte å lägg till de globala variablerna och fyra plot

/* Overbought Oversold Indicator
Globala variabler, gå till inställningar och lägg till nedan
ys1  : dataseries
rk3  : dataseries
rk5  : dataseries
rk6  : dataseries
up   : dataseries
down : dataseries
Oo   : dataseries
Cc   : dataseries
plot1, blå, signal
plot2, svart, noll linje
plot3, grön linje
plot4, röd linje
*/
local n = 5;  // Hårdkodad length, ändra vid behov

// Beräkna ys1 (global dataseries)
ys1[0] = (High[0] + Low[0] + Close[0] * 2) / 4;

// rk3: EMA på ys1 (global dataseries)
rk3[0] = ys1.ema(n);

// rk4: stdev på ys1
local rk4 = ys1.stdDev(n);

// rk5: Normaliserad värde (global dataseries)
rk5[0] = (ys1[0] - rk3[0]) * 100 / rk4;

// rk6: EMA på rk5 (global dataseries)
rk6[0] = rk5.ema(n);

// up: EMA på rk6 (global dataseries)
up[0] = rk6.ema(n);

// down: EMA på up (global dataseries)
down[0] = up.ema(n);

// Oo: iff-logik (nu global dataseries för att stödja Oo[-1])
Oo[0] = iff(up[0] < down[0], up[0], down[0]);

// Cc: iff-logik (nu global dataseries för att stödja Cc[-1])
Cc[0] = iff(up[0] < down[0], down[0], up[0]);

// Barcolor-logik (kommenterad - HK har ingen barcolor, kan användas för signal t.ex. plot4[0] = b_color;)
local b_color = iff(Oo[-1] < Oo[0] && Cc[0] < Cc[-1], 1,
                iff(up[0] > down[0], 2, 3));

// Plotting
local signal_buy         = up[-1] <= down[-1] && up[0] > down[0]
local signal_sell        = up[-1] >= down[-1] && up[0] < down[0]
plot2[0] = 0;          // Mittlinje
plot3[0] = up[0];      // Grön linje (up)
plot4[0] = down[0];    // Röd linje (down)
/* visa signal när grön linje korsar upp över röd linje och tvärt om
if(signal_buy == true)
	plot1[0] = 1
if(signal_sell == true)
	plot1[0] = -1
*/